home *** CD-ROM | disk | FTP | other *** search
/ Chaos 3 / Chaos_3_1997-06_-_de_Side_A.d64 / 003.the olly (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  4KB  |  161 lines
  1. 1 rem **** autor unbekannt!
  2. 2 rem **** (anm. von hardcore techno)
  3. 100 poke53280,0:poke53281,0:printchr$(152);chr$(147);
  4. 110 printtab(4);"================================="
  5. 120 printtab(4);"loeschen und schuetzen von files"
  6. 130 printtab(4);"================================="
  7. 140 print:print
  8. 150 print"mit diesem programm koennen files ge-"
  9. 160 print"schuetzt,  geloescht  und  freigegeben"
  10. 170 print"werden."
  11. 180 print:print
  12. 190 printtab(6);" -1- auflisten aller files":print
  13. 200 printtab(6);" -2- schuetzen eines files":print
  14. 210 printtab(6);" -3- freigeben eines files":print
  15. 220 printtab(6);" -4- loeschen eines files":print
  16. 230 printtab(6);" -5- beenden des programms":print
  17. 240 getx$:ifx$=""orval(x$)<1orval(x$)>5then240
  18. 250 ifval(x$)=5then end
  19. 260 onval(x$)gosub280,360,610,860
  20. 270 goto100
  21. 280 rem ---------------------
  22. 290 rem auflisten aller files
  23. 300 rem ---------------------
  24. 310 printchr$(147)
  25. 320 fl=1:gosub1190
  26. 330 print:print"weiter mit return"
  27. 340 inputx$
  28. 350 fl=0:return
  29. 360 rem ---------------------
  30. 370 rem schuetzen eines files
  31. 380 rem ---------------------
  32. 390 gosub1580
  33. 400 gosub1190
  34. 410 ifgf= 1 then460
  35. 420 print"file nicht gefunden!":print
  36. 430 print"weiter mit return!"
  37. 440 inputx$:close2:close15
  38. 450 return
  39. 460 print#15,"b-p:"2;x*32+2
  40. 470 get#2,x$:ifx$=""thenx$=chr$(0)
  41. 480 ft=asc(x$)
  42. 490 if(ft and 64)=0then510
  43. 500 print"file ist bereits geschuetzt!":print:goto430
  44. 510 ft=(ft or 64)
  45. 520 print#15,"b-p:"2;x*32+2
  46. 530 print#2,chr$(ft);
  47. 540 print#15,"b-p:"2;0
  48. 550 print#15,"u2:"2;0;tt;ss
  49. 560 close2:close15
  50. 570 print"file geschuetzt!"
  51. 580 print"weiter mit return!"
  52. 590 inputx$
  53. 600 close2:close15:return
  54. 610 rem ---------------------
  55. 620 rem freigeben eines files
  56. 630 rem ---------------------
  57. 640 gosub1580
  58. 650 gosub1190
  59. 660 ifgf= 1 then710
  60. 670 print"file nicht gefunden!":print
  61. 680 print"weiter mit return!"
  62. 690 inputx$:close2:close15
  63. 700 return
  64. 710 print#15,"b-p:"2;x*32+2
  65. 720 get#2,x$:ifx$=""thenx$=chr$(0)
  66. 730 ft=asc(x$)
  67. 740 if(ft and 64)=64 then760
  68. 750 print"file ist bereits freigegeben!":print:goto680
  69. 760 ft=(ft and 255-64)
  70. 770 print#15,"b-p:"2;x*32+2
  71. 780 print#2,chr$(ft);
  72. 790 print#15,"b-p:"2;0
  73. 800 print#15,"u2:"2;0;tt;ss
  74. 810 close2:close15
  75. 820 print"file freigegeben!"
  76. 830 print"weiter mit return!"
  77. 840 inputx$
  78. 850 return
  79. 860 rem ---------------------
  80. 870 rem loeschen eines files
  81. 880 rem ---------------------
  82. 890 gosub1580
  83. 900 gosub1190
  84. 910 ifgf= 1 then960
  85. 920 print"file nicht gefunden!":print
  86. 930 print"weiter mit return!"
  87. 940 inputx$:close2:close15
  88. 950 return
  89. 960 print#15,"b-p:"2;x*32+2
  90. 970 get#2,x$:ifx$=""thenx$=chr$(0)
  91. 980 ft=asc(x$)
  92. 990 if(ft and 64)=0then1040
  93. 1000 print"achtung! file ist geschuetzt!"
  94. 1010 print"freigeben und loeschen (j/n)?"
  95. 1020 getx$:ifx$=""orx$<>"n"andx$<>"j"then1020
  96. 1030 ifx$="n"then1170
  97. 1040 print"sicher (j/n)?"
  98. 1050 getx$:ifx$=""orx$<>"n"andx$<>"j"then1050
  99. 1060 ifx$="n"then1170
  100. 1070 ft=(ft and 255-64)
  101. 1080 print#15,"b-p:"2;x*32+2
  102. 1090 print#2,chr$(ft);
  103. 1100 print#15,"b-p:"2;0
  104. 1110 print#15,"u2:"2;0;tt;ss
  105. 1120 print#15,"i0:"
  106. 1130 print#15,"s:"+f$
  107. 1140 print"file geloescht!"
  108. 1150 print"weiter mit return!"
  109. 1160 inputx$
  110. 1170 close2:close15:return
  111. 1180 rem
  112. 1190 rem ------------------------
  113. 1200 rem lesen / suchen von files
  114. 1210 rem ------------------------
  115. 1220 open15,8,15,"i0":open2,8,2,"#"
  116. 1230 print#15,"u1:"2;0;18;0
  117. 1240 print#15,"b-p:"2;0
  118. 1250 print#15,"u2:"2;0;18;0
  119. 1260 input#15,x1$
  120. 1270 ifval(x1$)<>26then1330
  121. 1280 print"bitte vor benutzung dieses programms den";
  122. 1290 print"schreibschutz entfernen!"
  123. 1300 print"weiter mit return!"
  124. 1310 inputx$
  125. 1320 close2:close15:return
  126. 1330 t=18:s=1:tt=18:ss=1
  127. 1340 print#15,"u1:"2;0;t;s
  128. 1345 tt=t:ss=s
  129. 1350 print#15,"b-p:"2;0
  130. 1360 get#2,x$:ifx$=""thenx$=chr$(0)
  131. 1370 t=asc(x$)
  132. 1380 get#2,x$:ifx$=""thenx$=chr$(0)
  133. 1390 s=asc(x$)
  134. 1400 forx=0to7
  135. 1410 print#15,"b-p:"2;x*32+2
  136. 1420 get#2,x$:ifx$=""thenx$=chr$(0)
  137. 1430 ifasc(x$)=0then1530
  138. 1440 print#15,"b-p:"2;x*32+5
  139. 1450 ff$=""
  140. 1460 fory=0to15
  141. 1470 get#2,x$:ifx$=""thenx$=chr$(0)
  142. 1480 ifasc(x$)=160then 1500
  143. 1490 ff$=ff$+x$
  144. 1500 nexty
  145. 1510 ifflthenprintff$:goto1530
  146. 1520 iff$=ff$thengf=1:goto1570
  147. 1530 nextx
  148. 1540 ift<>0then1340
  149. 1550 close2:close15
  150. 1560 if fl=0thenprint"filename nicht gefunden!":fori=1to2000:next
  151. 1570 return
  152. 1580 rem ----------------------
  153. 1590 rem eingabe des filenamens
  154. 1600 rem ----------------------
  155. 1610 print:print
  156. 1620 input"name des files:";f$
  157. 1630 iflen(f$)<=16then1650
  158. 1640 print"filename zu lang!":goto1620
  159. 1650 gf=0:fl=0
  160. 1660 return
  161.